ES:Argentina/Cultura/GLAM/Snippets

From OpenStreetMap Wiki
Jump to navigation Jump to search
Argentina/Cultura/GLAM/Snippets - Other languages

tips and tricks & Howto's

Listar los museos con Overpass-turbo [https://overpass-turbo.eu/]

snippet
Ponerle límite a la consulta con un timeout de 25" 
[timeout:25];
Devuelve los datos en JSON o XML 
[out:json]

[out:xml]
Mapa de museos de CABA Normalmente haríamos esta consulta, que nos devuelve node, way y relation con sus elementos...
{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum](area.ciudad);
out body; >; out skel qt;
Pero en varias ocasiones precisamos solo un par de coordenadas. Esto se aplica, por ejemplo, cuando necesitamos crear un mapa con uMap, cuando creamos un nodo en Wikidata, o cuando no podemos o necesitamos más detalles. 'out center' nos devuelve las coordenadas calculadas del centro del objeto.
{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum](area.ciudad);
out center; >;
Devuelve los datos en CSV y nos da el total.


Nota: Esta consulta debe ser armada, detallando los campos requeridos; ver manual en: https://wiki.openstreetmap.org/wiki/Overpass_API/Overpass_QL#CSV_output_mode 

[out:csv(::type,::id,"name","museum_type","wikidata",::count)];
area[name="Ciudad Autónoma de Buenos Aires"]->.a;
nwr(area.a)[tourism=museum];
out;
out count;
Ver en overpass-turbo una consulta (casi todos los campos) : https://overpass-turbo.eu/s/Jyg


En JOSM usar esta consulta (para que nos devuelva todos los nodos que componen las vías).
[out:csv(::type,::id,"name","museum_type","wikidata",::count)];
{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum](area.ciudad);
out meta; >; out meta qt;

Devuelve los datos en CSV, con coordenadas para nwr y nos da el total de registros. 
[out:csv(::type,::id,::lat,::lon,"name","addr:city",::count)];
area[name="Ciudad Autónoma de Buenos Aires"]->.a;
nwr(area.a)[tourism=museum];
out center;
out count;
Ver en overpass-turbo una consulta con más campos: https://overpass-turbo.eu/s/J4L
Buscar museos (cadena 'museo' dentro de 'name'), galerías y obras de arte (museum | artwork | gallery) duplicados o duplicados y sin nombres (dentro de los 50m) en Argentina. 
area[name="Argentina"][admin_level=2][boundary=administrative]->.argentina;
(
 nwr(area.argentina)["tourism"~"(museum|artwork|gallery)"]->.a;
);
(
 nwr(around.a:50)[!tourism][name~"museo",i];  
 nwr(around.a:50)["tourism"~"(museum|artwork|gallery)"][!name];
);
(._;>;);
out meta;
Ver en overpass-turbo: https://overpass-turbo.eu/s/J4V
Lista los museos localizados en Colombia

https://overpass-turbo.eu/s/GN2 

{{geocodeArea:colombia}}->.a; // Area a buscar
nwr[tourism=museum](area.a); // Consulta de etiqueta
out body; >; out skel qt; // Mostrar resultado
Para restringirte a tu área simplemente modifica el geocodeArea.
{{geocodeArea:caba}}->.varLugar;
{{geocodeArea:Provincia de Buenos Aires, Argentina}}->.varLugar2;
{{geocodeArea:San Luis, Argentina}}->.varLugar3;

{{geocodeArea:Bolivia}}->.varPais;
Lista los museos localizados dos localidades

https://overpass-turbo.eu/s/GN3

Ejemplo de Argentina, que tiene museos en la Antártida, por lo que se debe buscar en ambas
area[name="Argentina"][admin_level=2]->.lugar1;
nwr(area.lugar1)[tourism=museum];
out body; >; out skel qt;

area[name="Antártida Argentina"][boundary=region]->.lugar2;
nwr(area.lugar2)[tourism=museum];
out body; >; out skel qt;
Ver en overpass-turbo : https://overpass-turbo.eu/s/CXu
Lista los museos localizados en CABA sin acceso a sillas de ruedas ["wheelchair"="no"]

https://overpass-turbo.eu/s/GN4 

{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum][wheelchair=no](area.ciudad);
out body; >; out skel qt;
Lista museos de CABA sin 'description'. 
area(3601224652)->.a; 
nwr[tourism=museum](area.a)
  ["description"!~"."]; 
out body; >; out skel qt;
Variante usando 'geocodeArea'
{{geocodeArea:CABA}}->.a; 
nwr[tourism=museum](area.a)
  ["description"!~"."]; 
out body; >; out skel qt;

Lista los museos localizados de CABA, que sean museos de arte, que se encuentren en el CP C1425AAS y no tengan acceso a sillas de ruedas.

https://overpass-turbo.eu/s/GN5 

{{geocodeArea:CABA}}->.ciudad;
nwr[tourism=museum] [museum=art] ["addr:postcode"="C1425AAS"] [wheelchair=no](area.ciudad);
out body; >; out skel qt;
Lista los nodos, vías y/o relaciones localizados en Argentina 'operados' por la Dirección Nacional de Museos.

https://overpass-turbo.eu/s/GN6 

{{geocodeArea:Argentina}}->.Pais;
nwr[operator="Dirección Nacional de Museos"](area.Pais);
out body; >; out skel qt;
Lista obras de arte exhibidas, principalmente, en museos de Argentina.

https://overpass-turbo.eu/s/GN7 

[out:json][timeout:25];
      {{geocodeArea:Argentina}}->.a; 
      area[name="Argentina"][admin_level=2]->.lugar1;
(
  nwr["exhibit"] (area.a);
);
out body; >; out skel qt;
Buscar 'place' en la Antártida Argentina con ayuda de Wikidata 
area[name="Antártida Argentina"][wikidata="Q646243"];
nwr (area) [place];
out body; >; out skel qt;
Nodos con por lo menos un tag (mayor a cero) en un área determinada por 'bbox' 
node({{bbox}})(if:count_tags() > 0);
out body; >; out skel qt;
NodeWatRelation "tourism"="museum" con solo 2 tags 
nwr({{bbox}})[tourism=museum](if:count_tags() == 2);
out body; >; out skel qt;
Variante : NodeWatRelation con un sólo 2 tags (es la opción 'i' para buscar mayúsculas y minúsculas)
nwr({{bbox}})["tourism"~"museum",i](if:count_tags() == 2);
out body; >; out skel qt;
Museo donde 'start_date' es mayor a 100 días.

https://overpass-turbo.eu/s/GN9 

node["tourism"="museum"](if:date(t["start_date"])<date("{{date:100 days}}"))({{bbox}});
out body; >; out skel qt;
Selecciona los museos con un 'start_date' mayor a * días 
node["tourism"="museum"][start_date~".*"](if:date(t["start_date"])<date("{{date:20000 days}}"))({{bbox}});
out body; >; out skel qt;
Selecciona los objetos que han sido añadidos o modificados más recientemente que la fecha.

https://overpass-turbo.eu/s/GNa 

{{geocodeArea:argentina}}->.searchArea;
node["tourism"="museum"](newer:"2018-10-06T00:00:01")(area.searchArea);
out body; >; out skel qt;
Busca los 'NodeWayRelation' que el 'user' no editó pasado * tiempo 
{{geocodeArea:Argentina}}->.searchArea;
((
  nwr[tourism=museum](area.searchArea);
); - /* este menos es para restar */
(
  nwr["tourism"="museum"](user:"martingggg")(newer:"2018-05-10T00:00:01")(area.searchArea);
););
out body; >; out skel qt;
Museos de Argentina sin [phone] 
      {{geocodeArea:argentina}}->.a; 
      nwr[tourism=museum](area.a)
        ["phone"!~"."]; 
      out body; >; out skel qt;
variante 
      area(3600286393)->.a; 
      nwr[tourism=museum](area.a)
        ["phone"!~"."]; 
      out body; >; out skel qt;
Consulta los (nwr) museos, pregunta si existe la etiqueta "opening_hours", si hay alguno que abra de 8 a 12:30 y por último pregunta si no tiene la etiqueta "wheelchair", en el área de la ventana actaual.

https://overpass-turbo.eu/s/GNb 

nwr["tourism"="museum"]
  ["opening_hours"]
  ["opening_hours"!="08:30-12:30"] ({{bbox}})
  ["wheelchair"!~"."]; 
  out body; >; out skel qt;
Todos los museos del mundo ;-)

Esta query demanda muchos recursos por lo que quizá debieras incrementar el tiempo de ejecución. Prueba agregandole [timeout:50]; 

node["tourism"="museum"];
out body; >; out skel qt;
Si queres que sea compatible con Level0 o JOSM... 
out body; >; out skel qt;
por
out meta; >; out meta qt;

Más snippets interesantes de OverPass Turbo

ID

Copiar y pegar tags, ideal para cuando tienes que pasar los tags de un nodo a una way:  ;-)

Consultas varias con Wikidata Query Service (WQS) [https://query.wikidata.org/]

snippet
Lista los museos de Argentina 
SELECT DISTINCT ?entity ?entityLabel ?value ?valueLabel WHERE {
  ?entity (wdt:P31/(wdt:P279*)) wd:Q33506;
    wdt:P17 ?countries.
  FILTER(?countries IN(wd:Q28, wd:Q34, wd:Q36, wd:Q38, wd:Q39, wd:Q40, wd:Q77, wd:Q142, wd:Q145, wd:Q183, wd:Q212, wd:Q233, wd:Q252, wd:Q298, wd:Q399, wd:Q403, wd:Q414, wd:Q657, wd:Q668, wd:Q962, wd:Q963, wd:Q974, wd:Q1006, wd:Q1036, wd:Q1033, wd:Q1037, wd:Q29999))
  ?entity wdt:P17 wd:Q414;
    p:P625 ?prop.
  OPTIONAL { ?prop ps:P625 ?value. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Lista los museos de Argentina [obsoleto] 
SELECT DISTINCT ?museo ?p131Label ?coordenadas ?coordenadasLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?museo (p:P31/ps:P31/(wdt:P279*)) wd:Q33506;
    wdt:P131 ?p131.
  wd:Q414 (wdt:P150*) ?p131.
  OPTIONAL {  }
  OPTIONAL { ?museo wdt:P625 ?coordenadas. }
  OPTIONAL {  }
}
LIMIT 1000
All items whit the property set 
SELECT DISTINCT ?entity ?entityLabel ?value ?valueLabel WHERE {
  ?entity (wdt:P31/(wdt:P279*)) wd:Q33506;
    wdt:P17 ?countries.
  FILTER(?countries IN(wd:Q28, wd:Q34, wd:Q36, wd:Q38, wd:Q39, wd:Q40, wd:Q142, wd:Q145, wd:Q183, wd:Q212, wd:Q233, wd:Q298, wd:Q399, wd:Q403, wd:Q414, wd:Q657, wd:Q1356, wd:Q29999))
  ?entity wdt:P17 wd:Q414;
    p:P625 ?prop.
  OPTIONAL { ?prop ps:P625 ?value. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
All items whitout the property set 
SELECT DISTINCT ?entity ?entityLabel WHERE {
  ?entity (wdt:P31/(wdt:P279*)) wd:Q33506;
    wdt:P17 ?countries.
  FILTER(?countries IN(wd:Q28, wd:Q34, wd:Q36, wd:Q38, wd:Q39, wd:Q40, wd:Q142, wd:Q145, wd:Q183, wd:Q212, wd:Q233, wd:Q298, wd:Q399, wd:Q403, wd:Q414, wd:Q657, wd:Q1356, wd:Q29999))
  ?entity wdt:P17 wd:Q414.
  MINUS {
    { ?entity rdf:type wdno:P625. }
    UNION
    { ?entity wdt:P625 ?prop. }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Listas los museos de Argentina con entradas en Buenos Aires 
SELECT ?item ?itemLabel ?coordinates WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q33506.
  ?item wdt:P131 wd:Q1486.
  ?item wdt:P625 ?coordinates.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es, en". }
}
Museos en Buenos Aires 
SELECT DISTINCT ?item ?name ?coord ?lat ?lon ?URL_de_una_imagen_compatible_con_Commons WHERE {
  hint:Query hint:optimizer "None".
  ?item (wdt:P131*) wd:Q1486;
    (wdt:P31/(wdt:P279*)) wd:Q33506;
    wdt:P625 ?coord;
    p:P625 ?coordinate.
  ?coordinate psv:P625 ?coordinate_node.
  ?coordinate_node wikibase:geoLatitude ?lat;
    wikibase:geoLongitude ?lon.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?item rdfs:label ?name.
  }
  OPTIONAL { ?item wdt:P18 ?URL_de_una_imagen_compatible_con_Commons. }
}
ORDER BY (?name)
Museos en Instagram

Fuente: https://www.wikidata.org/wiki/Wikidata:SPARQL_query_service/Building_a_query/Museums_on_Instagram 

    #defaultView:Map
SELECT ?item ?itemLabel ?instagram ?coordinates WHERE {
  ?item wdt:P31/wdt:P279* wd:Q33506 ;
        wdt:P2003 ?instagram ;
        wdt:P625 ?coordinates .
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" } .
}
Museums in Argentina without a label in Ukrainian 
SELECT DISTINCT ?entity ?entityLabel WHERE {  
 ?entity (wdt:P31/(wdt:P279*)) wd:Q33506;
 wdt:P17 wd:Q414 . 
 ?entity wdt:P17 wd:Q414 . 
  MINUS { { ?entity rdfs:label ?lang_label. FILTER((LANG(?lang_label)) = "uk") } }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es". }
 }
Museums in Guinea without a description in Spanish 
SELECT DISTINCT ?entity ?entityLabel WHERE {
  ?entity (wdt:P31/(wdt:P279*)) wd:Q33506;
  wdt:P17 wd:Q1006 . 
  ?entity wdt:P17 wd:Q1006 .  
  MINUS { { ?entity schema:description ?lang_label. FILTER((LANG(?lang_label)) = "es") } }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
 }
People who work or have worked at museums in the Netherlands without label in Polish 
SELECT DISTINCT ?museumPeople ?museumPeopleLabel
WHERE 
{
?museum wdt:P31/wdt:P279* wd:Q33506;
wdt:P17 wd:Q40.
?museumPeople wdt:P108 ?museum MINUS { { ?museumPeople rdfs:label ?lang_label. FILTER((LANG(?lang_label)) = "pl") }  }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". }
}
People who work or have worked at museums in West Bengal without label in French 
SELECT DISTINCT ?museumPeople ?museumPeopleDescription
WHERE 
{
  wd:Q33506 ^wdt:P279*/^wdt:P31 ?museum . 
  ?museum wdt:P131+ wd:Q1356. 
?museumPeople wdt:P108 ?museum MINUS { { ?museumPeople rdfs:description ?lang_label. FILTER((LANG(?lang_label)) = "fr") }  }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],bn". }
}
Objects or events at museums in Chile without label in German 
SELECT DISTINCT ?entity ?entityLabel WHERE {
  ?entity wdt:P276 [(wdt:P31/(wdt:P279*)) wd:Q33506; ];
  wdt:P17 wd:Q298. 
  ?entity wdt:P17 wd:Q298. MINUS { { ?entity rdfs:label ?lang_label. FILTER((LANG(?lang_label)) = "de") }  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es". }
  }
Objects or events at museums in Bénin without description in Italian 
SELECT DISTINCT ?entity ?entityLabel WHERE {
  ?entity wdt:P276 [(wdt:P31/(wdt:P279*)) wd:Q33506; ];
  wdt:P17 wd:Q962. 
  ?entity wdt:P17 wd:Q962. MINUS { { ?entity rdfs:description ?lang_label. FILTER((LANG(?lang_label)) = "it") }  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }
  }
authors in elem and wikidata 
#defaultView:Map{"hide": ["?coord"]}
#Query by Silvia Gutiérrez (@espejolento)

SELECT ?author ?authorLabel ?birthplaceLabel ?idELEM ?coord

(GROUP_CONCAT(DISTINCT ?occupation_label; SEPARATOR=", ") as ?occupations) #thanks to @NavinoEvans for this!

WHERE {
      ?author wdt:P1565 ?idELEM . #has a ELEM id   
       OPTIONAL {
        ?author wdt:P19 ?birthplace .   # born in a place...
         ?birthplace wdt:P625 ?coord .
         ?author wdt:P106 ?occupation . #get occupation
         ?occupation rdfs:label ?occupation_label FILTER (lang(?occupation_label) = "es") #get label the 'manual' way 
       }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es". }        
} GROUP BY ?author ?authorLabel ?birthplaceLabel ?idELEM ?coord #GROUP BY
LIMIT 5000
german women writers in GND and wikidata 
#defaultView:Map{"hide": ["?coord"]}
#Query by Silvia Gutiérrez (@espejolento)
SELECT ?author ?authorLabel ?lugarnacimientoLabel ?idGND ?coord ?birthyear (GROUP_CONCAT(DISTINCT ?occupation_label; SEPARATOR = ", ") AS ?occupations) WHERE {
  ?author wdt:P227 ?idGND; #has GND id
    wdt:P21 wd:Q6581072; #female
    wdt:P106 wd:Q36180; #writer
    wdt:P19 ?lugarnacimiento.
  ?lugarnacimiento wdt:P17 wd:Q183; #born in Germany
    wdt:P625 ?coord.
  OPTIONAL {
    ?author wdt:P106 ?occupation.
    ?occupation rdfs:label ?occupation_label.
    FILTER((LANG(?occupation_label)) = "en")
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?author ?authorLabel ?lugarnacimientoLabel ?idGND ?coord ?birthyear
LIMIT 5000
latin american authors born today 
#Escritoras/es que nacieron "el día de hoy"
#defaultView:Map{"hide": ["?coord"]}
#Query by Silvia Gutiérrez (@espejolento)

SELECT ?personItem ?person ?personDescription  ?date ?Country_of_citizenship ?Occupation  ?Gender ?image ?rank ?Cause_of_death ?Ethnic_group ?Education ?coord (CONCAT(?person,' (',?personDescription,')') as ?title)
WHERE {
{
SELECT ?personItem ?date ?countryItem ?genderItem ?causeOfDeathItem ?ethnicGroupItem ?educatedAtItem ?coord
(SAMPLE(?image) as ?image)
(COUNT(?article) as ?rank) 
WHERE {	
?personItem wdt:P569 ?date .
?personItem wdt:P18 ?image .
?personItem wdt:P21 ?genderItem .
?personItem wdt:P106 wd:Q36180 .
?personItem wdt:P19 ?birthplace .   
?birthplace wdt:P17 ?countryItem .  
?countryItem p:P361/ps:P361 wd:Q12585 .
?countryItem wdt:P625 ?coord .
OPTIONAL { ?personItem wdt:P509 ?causeOfDeathItem }
OPTIONAL { ?personItem wdt:P172 ?ethnicGroupItem }
OPTIONAL { ?personItem wdt:P69 ?educatedAtItem }
OPTIONAL { ?article schema:about ?personItem }
FILTER (datatype(?date) = xsd:dateTime && month(?date) = month(now()) && day(?date) = day(now()))	
} GROUP BY ?personItem ?date ?countryItem ?genderItem ?causeOfDeathItem ?ethnicGroupItem ?educatedAtItem ?coord
}
SERVICE wikibase:label {
bd:serviceParam wikibase:language 'es' .
?personItem schema:description ?personDescription .
?personItem rdfs:label ?person .
?countryItem rdfs:label ?Country_of_citizenship .
?genderItem rdfs:label ?Gender .
?causeOfDeathItem rdfs:label ?Cause_of_death .
?ethnicGroupItem rdfs:label ?Ethnic_group .
?educatedAtItem rdfs:label ?Education .
}
}  ORDER BY DESC(?rank)
map painting location by painter 
#defaultView:Map
#consulta de Silvia Gutiérrez @espejolento
SELECT ?subjLabel ?coord ?subj
WHERE
{
   ?subj wdt:P170 wd:Q315647 . #Puedes editar el nombre de el/la artista aquí
  OPTIONAL {?subj wdt:P276 ?loc .
    ?loc wdt:P625 ?coord } 
    #la sig línea es para obtener el título de la pintura en español si se puede o en su defecto, en AUTO_LANGUAGE (o sea en inglés)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es".} 
}
novels wikipedia links by latam authors 
#Consulta de Silvia Gutiérrez @espejolento
SELECT ?item ?itemLabel ?authorLabel ?linkCount WHERE {
  ?item wdt:P31 wd:Q8261;
        wdt:P50 ?author .
  ?author wdt:P19 ?birthplace .
  ?birthplace wdt:P17 ?countryItem .  
?countryItem p:P361/ps:P361 wd:Q12585 .
  ?item wikibase:sitelinks ?linkCount . #cuántos artículos en otro idioma
    ?article schema:about ?item .
    ?article schema:isPartOf <https://es.wikipedia.org/> . #has wikipedia article
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es". }
}
LIMIT 10000
peruvian female writers 
#defaultView:Map{"hide": ["?coord"]}
#Query by Silvia Gutiérrez (@espejolento)
SELECT ?author ?authorLabel ?birthplaceLabel ?coord (GROUP_CONCAT(DISTINCT ?occupation_label; SEPARATOR = ", ") AS ?occupations) WHERE {
  ?author wdt:P21 wd:Q6581072;
    wdt:P106 wd:Q36180;
    wdt:P19 ?birthplace.
  ?birthplace wdt:P17 wd:Q419;
    wdt:P625 ?coord.
  OPTIONAL {
    ?author wdt:P106 ?occupation.
    ?occupation rdfs:label ?occupation_label.
    FILTER((LANG(?occupation_label)) = "es")
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es". }
}
GROUP BY ?author ?authorLabel ?birthplaceLabel ?coord
LIMIT 200
wikipedia links by author 
#Consulta de Silvia Gutiérrez @espejolento
SELECT ?item ?itemLabel ?linkCount WHERE {
  ?item wdt:P50 wd:Q5682. #autor es Cervantes
  ?item wikibase:sitelinks ?linkCount . #cuántos artículos en otro idioma
    ?article schema:about ?item .
    ?article schema:isPartOf <https://es.wikipedia.org/> . #has wikipedia article
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es". }
}
LIMIT 1000
women authors from brasil in library of congress 
#defaultView:Map{"hide": ["?coord"]}
#Query by Silvia Gutiérrez (@espejolento)
SELECT ?author ?authorLabel ?birthplaceLabel ?LCSH ?coord (GROUP_CONCAT(DISTINCT ?occupation_label; SEPARATOR = ", ") AS ?occupations) WHERE {
  ?author wdt:P244 ?LCSH;
    wdt:P21 wd:Q6581072;
    wdt:P106 wd:Q36180;
    wdt:P19 ?birthplace.
  ?birthplace wdt:P17 wd:Q155;
    wdt:P625 ?coord.
  OPTIONAL {
    ?author wdt:P106 ?occupation.
    ?occupation rdfs:label ?occupation_label.
    FILTER((LANG(?occupation_label)) = "es")
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],es". }
}
GROUP BY ?author ?authorLabel ?birthplaceLabel ?LCSH ?coord
LIMIT 5000

Otros snippets Wikidata

Wikidata: SPARQL Tutorial


Retrieved from "https://wiki.openstreetmap.org/w/index.php?title=ES:Argentina/Cultura/GLAM/Snippets&oldid=2322690"